3 files changed, 227 insertions, 7 deletions

diff --git a/client/shaders/nodes_shader/opengl_vertex.glsl b/client/shaders/nodes_shader/opengl_vertex.glsl
index bbf7b1d65..ccff1260d 100644
--- a/client/shaders/nodes_shader/opengl_vertex.glsl
+++ b/client/shaders/nodes_shader/opengl_vertex.glsl
@@ -46,6 +46,42 @@ float smoothTriangleWave(float x)
 	return smoothCurve(triangleWave(x)) * 2.0 - 1.0;
 }
 
+// OpenGL < 4.3 does not support continued preprocessor lines
+#if (MATERIAL_TYPE == TILE_MATERIAL_WAVING_LIQUID_TRANSPARENT || MATERIAL_TYPE == TILE_MATERIAL_WAVING_LIQUID_OPAQUE || MATERIAL_TYPE == TILE_MATERIAL_WAVING_LIQUID_BASIC) && ENABLE_WAVING_WATER
+
+//
+// Simple, fast noise function.
+// See: https://gist.github.com/patriciogonzalezvivo/670c22f3966e662d2f83
+//
+vec4 perm(vec4 x)
+{
+	return mod(((x * 34.0) + 1.0) * x, 289.0);
+}
+
+float snoise(vec3 p)
+{
+	vec3 a = floor(p);
+	vec3 d = p - a;
+	d = d * d * (3.0 - 2.0 * d);
+
+	vec4 b = a.xxyy + vec4(0.0, 1.0, 0.0, 1.0);
+	vec4 k1 = perm(b.xyxy);
+	vec4 k2 = perm(k1.xyxy + b.zzww);
+
+	vec4 c = k2 + a.zzzz;
+	vec4 k3 = perm(c);
+	vec4 k4 = perm(c + 1.0);
+
+	vec4 o1 = fract(k3 * (1.0 / 41.0));
+	vec4 o2 = fract(k4 * (1.0 / 41.0));
+
+	vec4 o3 = o2 * d.z + o1 * (1.0 - d.z);
+	vec2 o4 = o3.yw * d.x + o3.xz * (1.0 - d.x);
+
+	return o4.y * d.y + o4.x * (1.0 - d.y);
+}
+
+#endif
 
 void main(void)
 {
@@ -65,7 +101,8 @@ void main(void)
 
 float disp_x;
 float disp_z;
-#if (MATERIAL_TYPE == TILE_MATERIAL_WAVING_LEAVES && ENABLE_WAVING_LEAVES) || (MATERIAL_TYPE == TILE_MATERIAL_WAVING_PLANTS && ENABLE_WAVING_PLANTS)
+#if (MATERIAL_TYPE == TILE_MATERIAL_WAVING_LEAVES && ENABLE_WAVING_LEAVES) || \
+	(MATERIAL_TYPE == TILE_MATERIAL_WAVING_PLANTS && ENABLE_WAVING_PLANTS)
 	vec4 pos2 = mWorld * gl_Vertex;
 	float tOffset = (pos2.x + pos2.y) * 0.001 + pos2.z * 0.002;
 	disp_x = (smoothTriangleWave(animationTimer * 23.0 + tOffset) +
@@ -75,12 +112,21 @@ float disp_z;
 		smoothTriangleWave(animationTimer * 13.0 + tOffset)) * 0.5;
 #endif
 
+	worldPosition = (mWorld * gl_Vertex).xyz;
 
+// OpenGL < 4.3 does not support continued preprocessor lines
 #if (MATERIAL_TYPE == TILE_MATERIAL_WAVING_LIQUID_TRANSPARENT || MATERIAL_TYPE == TILE_MATERIAL_WAVING_LIQUID_OPAQUE || MATERIAL_TYPE == TILE_MATERIAL_WAVING_LIQUID_BASIC) && ENABLE_WAVING_WATER
+	// Generate waves with Perlin-type noise.
+	// The constants are calibrated such that they roughly
+	// correspond to the old sine waves.
 	vec4 pos = gl_Vertex;
-	pos.y -= 2.0;
-	float posYbuf = (pos.z / WATER_WAVE_LENGTH + animationTimer * WATER_WAVE_SPEED * WATER_WAVE_LENGTH);
-	pos.y -= sin(posYbuf) * WATER_WAVE_HEIGHT + sin(posYbuf / 7.0) * WATER_WAVE_HEIGHT;
+	vec3 wavePos = worldPosition + cameraOffset;
+	// The waves are slightly compressed along the z-axis to get
+	// wave-fronts along the x-axis.
+	wavePos.x /= WATER_WAVE_LENGTH * 3;
+	wavePos.z /= WATER_WAVE_LENGTH * 2;
+	wavePos.z += animationTimer * WATER_WAVE_SPEED * 10;
+	pos.y += (snoise(wavePos) - 1) * WATER_WAVE_HEIGHT * 5;
 	gl_Position = mWorldViewProj * pos;
 #elif MATERIAL_TYPE == TILE_MATERIAL_WAVING_LEAVES && ENABLE_WAVING_LEAVES
 	vec4 pos = gl_Vertex;
@@ -101,7 +147,6 @@ float disp_z;
 
 
 	vPosition = gl_Position.xyz;
-	worldPosition = (mWorld * gl_Vertex).xyz;
 
 	// Don't generate heightmaps when too far from the eye
 	float dist = distance (vec3(0.0, 0.0, 0.0), vPosition);
@@ -141,12 +186,12 @@ float disp_z;
 	color.rgb = gl_Color.rgb * (gl_Color.a * dayLight.rgb + 
 		nightRatio * artificialLight.rgb) * 2;
 	color.a = 1;
-	
+
 	// Emphase blue a bit in darker places
 	// See C++ implementation in mapblock_mesh.cpp final_color_blend()
 	float brightness = (color.r + color.g + color.b) / 3;
 	color.b += max(0.0, 0.021 - abs(0.2 * brightness - 0.021) +
 		0.07 * brightness);
-	
+
 	gl_FrontColor = gl_BackColor = clamp(color, 0.0, 1.0);
 }
diff --git a/client/shaders/object_shader/opengl_fragment.glsl b/client/shaders/object_shader/opengl_fragment.glsl
new file mode 100644
index 000000000..bb9e40637
--- /dev/null
+++ b/client/shaders/object_shader/opengl_fragment.glsl
@@ -0,0 +1,131 @@
+uniform sampler2D baseTexture;
+uniform sampler2D normalTexture;
+uniform sampler2D textureFlags;
+
+uniform vec4 emissiveColor;
+uniform vec4 skyBgColor;
+uniform float fogDistance;
+uniform vec3 eyePosition;
+
+varying vec3 vNormal;
+varying vec3 vPosition;
+varying vec3 worldPosition;
+
+varying vec3 eyeVec;
+varying vec3 lightVec;
+varying float vIDiff;
+
+bool normalTexturePresent = false;
+bool texTileableHorizontal = false;
+bool texTileableVertical = false;
+bool texSeamless = false;
+
+const float e = 2.718281828459;
+const float BS = 10.0;
+const float fogStart = FOG_START;
+const float fogShadingParameter = 1 / ( 1 - fogStart);
+
+void get_texture_flags()
+{
+	vec4 flags = texture2D(textureFlags, vec2(0.0, 0.0));
+	if (flags.r > 0.5) {
+		normalTexturePresent = true;
+	}
+	if (flags.g > 0.5) {
+		texTileableHorizontal = true;
+	}
+	if (flags.b > 0.5) {
+		texTileableVertical = true;
+	}
+	if (texTileableHorizontal && texTileableVertical) {
+		texSeamless = true;
+	}
+}
+
+float intensity(vec3 color)
+{
+	return (color.r + color.g + color.b) / 3.0;
+}
+
+float get_rgb_height(vec2 uv)
+{
+	if (texSeamless) {
+		return intensity(texture2D(baseTexture, uv).rgb);
+	} else {
+		return intensity(texture2D(baseTexture, clamp(uv, 0.0, 0.999)).rgb);
+	}
+}
+
+vec4 get_normal_map(vec2 uv)
+{
+	vec4 bump = texture2D(normalTexture, uv).rgba;
+	bump.xyz = normalize(bump.xyz * 2.0 - 1.0);
+	return bump;
+}
+
+void main(void)
+{
+	vec3 color;
+	vec4 bump;
+	vec2 uv = gl_TexCoord[0].st;
+	bool use_normalmap = false;
+	get_texture_flags();
+
+#if USE_NORMALMAPS == 1
+	if (normalTexturePresent) {
+		bump = get_normal_map(uv);
+		use_normalmap = true;
+	}
+#endif
+
+#if GENERATE_NORMALMAPS == 1
+	if (normalTexturePresent == false) {
+		float tl = get_rgb_height(vec2(uv.x - SAMPLE_STEP, uv.y + SAMPLE_STEP));
+		float t  = get_rgb_height(vec2(uv.x - SAMPLE_STEP, uv.y - SAMPLE_STEP));
+		float tr = get_rgb_height(vec2(uv.x + SAMPLE_STEP, uv.y + SAMPLE_STEP));
+		float r  = get_rgb_height(vec2(uv.x + SAMPLE_STEP, uv.y));
+		float br = get_rgb_height(vec2(uv.x + SAMPLE_STEP, uv.y - SAMPLE_STEP));
+		float b  = get_rgb_height(vec2(uv.x, uv.y - SAMPLE_STEP));
+		float bl = get_rgb_height(vec2(uv.x -SAMPLE_STEP, uv.y - SAMPLE_STEP));
+		float l  = get_rgb_height(vec2(uv.x - SAMPLE_STEP, uv.y));
+		float dX = (tr + 2.0 * r + br) - (tl + 2.0 * l + bl);
+		float dY = (bl + 2.0 * b + br) - (tl + 2.0 * t + tr);
+		bump = vec4(normalize(vec3 (dX, dY, NORMALMAPS_STRENGTH)), 1.0);
+		use_normalmap = true;
+	}
+#endif
+
+	vec4 base = texture2D(baseTexture, uv).rgba;
+
+#ifdef ENABLE_BUMPMAPPING
+	if (use_normalmap) {
+		vec3 L = normalize(lightVec);
+		vec3 E = normalize(eyeVec);
+		float specular = pow(clamp(dot(reflect(L, bump.xyz), E), 0.0, 1.0), 1.0);
+		float diffuse = dot(-E,bump.xyz);
+		color = (diffuse + 0.1 * specular) * base.rgb;
+	} else {
+		color = base.rgb;
+	}
+#else
+	color = base.rgb;
+#endif
+
+	vec4 col = vec4(color.rgb, base.a);
+
+	col.rgb *= emissiveColor.rgb * vIDiff;
+	// Due to a bug in some (older ?) graphics stacks (possibly in the glsl compiler ?),
+	// the fog will only be rendered correctly if the last operation before the
+	// clamp() is an addition. Else, the clamp() seems to be ignored.
+	// E.g. the following won't work:
+	//      float clarity = clamp(fogShadingParameter
+	//		* (fogDistance - length(eyeVec)) / fogDistance), 0.0, 1.0);
+	// As additions usually come for free following a multiplication, the new formula
+	// should be more efficient as well.
+	// Note: clarity = (1 - fogginess)
+	float clarity = clamp(fogShadingParameter
+		- fogShadingParameter * length(eyeVec) / fogDistance, 0.0, 1.0);
+	col = mix(skyBgColor, col, clarity);
+
+	gl_FragColor = vec4(col.rgb, base.a);
+}
diff --git a/client/shaders/object_shader/opengl_vertex.glsl b/client/shaders/object_shader/opengl_vertex.glsl
new file mode 100644
index 000000000..488089392
--- /dev/null
+++ b/client/shaders/object_shader/opengl_vertex.glsl
@@ -0,0 +1,44 @@
+uniform mat4 mWorldViewProj;
+uniform mat4 mWorld;
+
+uniform vec3 eyePosition;
+uniform float animationTimer;
+
+varying vec3 vNormal;
+varying vec3 vPosition;
+varying vec3 worldPosition;
+
+varying vec3 eyeVec;
+varying vec3 lightVec;
+varying float vIDiff;
+
+const float e = 2.718281828459;
+const float BS = 10.0;
+
+float directional_ambient(vec3 normal)
+{
+	vec3 v = normal * normal;
+
+	if (normal.y < 0)
+		return dot(v, vec3(0.670820f, 0.447213f, 0.836660f));
+
+	return dot(v, vec3(0.670820f, 1.000000f, 0.836660f));
+}
+
+void main(void)
+{
+	gl_TexCoord[0] = gl_TextureMatrix[0] * gl_MultiTexCoord0;
+	gl_Position = mWorldViewProj * gl_Vertex;
+
+	vPosition = gl_Position.xyz;
+	vNormal = gl_Normal;
+	worldPosition = (mWorld * gl_Vertex).xyz;
+
+	vec3 sunPosition = vec3 (0.0, eyePosition.y * BS + 900.0, 0.0);
+
+	lightVec = sunPosition - worldPosition;
+	eyeVec = -(gl_ModelViewMatrix * gl_Vertex).xyz;
+	vIDiff = directional_ambient(normalize(gl_Normal));
+
+	gl_FrontColor = gl_BackColor = gl_Color;
+}